[Zx81:Type-Ins] "Your Computer" campaign...

Discussion about ZX80 / ZX81 Software
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 05/82


"Magic Square"


/Basic game/

Contributor : Antipontifex.

Code: Select all

1 SLOW
10 PRINT AT 0,8;"< MAGIC SQUARES >"
12 PRINT AT 2,14;"816"
13 PRINT AT 3,14;"357"
14 PRINT AT 4,14;"492"
16 PRINT AT 6,1;"IN THE MAGIC SQUARE SHOWN ABOVE"
17 PRINT AT 7,0;"EACH ROW, COLUMN AND DIAGONAL"
18 PRINT AT 8,0;"ADDS UP TO 15. THERE ARE MANY"
19 PRINT AT 9,0;"DIFFERENT KINDS AND SIZES OF"
20 PRINT AT 10,0;"MAGIC SQUARES AND IN THIS GAME I"
21 PRINT AT 11,0;"CAN MAKE THEM WITH UP TO 49 NUM-"
22 PRINT AT 12,0;"BERS. ONCE I HAVE MADE A MAGIC"
23 PRINT AT 13,0;"SQUARE I WILL DISPLAY IT TO YOU"
24 PRINT AT 14,0;"WITH SOME NUMBERS MISSING. THE" 
25 PRINT AT 15,0;"GAME IS FOR YOU TO FILL IN THE" 
26 PRINT AT 15,0;"MISSING NUMBERS AS QUICKLY AS" 
27 PRINT AT 17,0;"POSSIBLE, IF YOU ARE QUICK YOU" 
28 PRINT AT 18,0;"WILL BE PROMOTED TO THE NEXT" 
29 PRINT AT 19,0;"BIGGER SQUARE. IF NOT, I WILL" 
30 PRINT AT 20,0;"EITHER LEAVE YOU OR RELEGATE YOU" 
31 PRINT AT 21,3;" ( PRESS RUN WHEN READY ) " 
32 IF INKEY$<>"R" THEN GOTO 32 
35 CLS 
40 PRINT AT 0,8;"< MAGIC SQUARES >"
42 PRINT AT 2,1;"THE AIM OF THE GAME IS TO GET" 
43 PRINT AT 3,0;"PROMOTED A HIGH AS POSSIBLE IN" 
44 PRINT AT 4,0;"600 SECONDS. THERE ARE THREE" 
45 PRINT AT 5,0;"DEGREES OF DIFFICULTY; START AS" 
46 PRINT AT 6,0;"A BEGINNER. I WILL ADVISE YOU" 
47 PRINT AT 7,0;"WHEN TO GO ON TO THE NEXT LEVEL." 
49 PRINT AT 9,1;"EXAMPLE:" 
50 PRINT AT 10,7;"MAGIC NUMBER IS 15" 
51 PRINT AT 11,12;"«««««««"
52 PRINT AT 12,8;"ROW1«2+7+?«" 
53 PRINT AT 13,8;"ROW2«9+5+?«"
54 PRINT AT 14,8;"ROW3«?+?+?«" 
55 PRINT AT 15,12;"«««««««"
56 PRINT AT 16,0;"ROW1: 7+2=9 ; 15-9=6 ; SO ?=6"
57 PRINT AT 17,0;"ROW2: 9+5=14; 15-14=1; SO ?=1" 
58 PRINT AT 18,0;"ROW3: 2+9=11; 15-11=4; SO ?=4"
59 PRINT AT 19,0;"ROW3: 7+5=12; 15-12=3; SO ?=3" 
60 PRINT AT 20,0;"ROW3: 6+1=7 ; 15-7=8 ; SO ?=8" 
61 PRINT AT 21,3;" < PRESS RUN WHEN READY > "
65 IF INKEY$<>"R" THEN GOTO 65 
70 CLS 
80 PRINT AT 12,0;"TYPE IN THE DEGREE OF DIFFICULTY"
82 PRINT AT 14,15;"B FOR BEGINNER"
84 PRINT AT 15,15;"E FOR EXPERT"
86 PRINT AT 16,15;"I FOR IMPOSSIBLE" 
88 LET D$=INKEY$ 
90 IF D$="B" OR D$="E" OR D$="I" THEN GOTO 95 
91 GOTO 88
95 LET Y=0
96 LET PREV=0
97 LET B=0
98 CLS
99 FAST
100 LET D=3
101 FOR J=0 TO 31
102 PRINT AT 9,J;"«"
103 IF J>=9 THEN GOTO 105
104 PRINT AT J,15;"«"
105 NEXT J
109 REM MAGIC SQUARE SETTING
110 LET X=1
120 LET ROW=1
121 FOR J=10 TO 20
122 PRINT AT J,0;"                                "
123 NEXT J
124 FAST
125 DIM I(D,D)
130 DIM M(D,D)
140 IF D=4 THEN GOTO 350
142 IF D=6 THEN GOTO 400
144 GOSUB 150
146 GOTO 500
150 LET C=INT(D/2)+1
160 LET M(ROW,C)=X
170 LET X=X+1
180 LET C=C+1
190 LET ROW=ROW-1
200 IF ROW<1 THEN GOTO 260
210 IF C>D THEN GOTO 290
220 IF M(ROW,C)>0 THEN GOTO 320
230 LET M(ROW,C)=X
240 IF X>=(D**2-0.1+Y) THEN RETURN
250 GOTO 170
260 IF C>D THEN GOTO 320
270 LET ROW=ROW+D
280 GOTO 230
290 LET C=C-D 
300 GOTO 230 
320 LET C=C-1
330 LET ROW=ROW+2
340 GOTO 230
350 REM FOURTH ORDER
352 FOR J=1 TO 4
353 FOR K=1 TO 4
354 LET M(J,K)=X+4*(J-1)+K-1 
355 NEXT K 
356 NEXT J 
358 FOR J=1 TO 2
360 LET I(J,J)=M(J,J)
362 LET M(J,J)=M(5-J,5-J)
364 LET M(5-J,5-J)=I(J,J)
366 LET K=5-J
368 LET I(J,K)=M(J,K) 
370 LET M(J,K)=M(K,J) 
372 LET M(K,J)=I(J,K) 
374 NEXT J 
376 GOTO 
400 REM SIXTH ORDER 
410 LET D=3 
420 GOSUB 150 
430 LET D=6 
432 FOR J=1 TO 3 
434 FOR K=1 TO 3 
436 LET M(J,K+3)=M(J,K)+18 
438 LET M(J+3,K)=M(J,K)+27 
440 LET M(J+3,K+3)=M(J,K)+9 
442 NEXT K 
444 NEXT J 
446 FOR J=1 TO 3 
448 LET K=1 
450 IF J=2 THEN LET K=2 
452 LET I(J,K)=M(J,K) 
454 LET M(J,K)=M(J+3,K) 
456 LET M(J+3,K)=I(J,K) 
458 NEXT J 
500 REM ROTATION AND REFLECTION 
510 LET R=RND
520 LET S=RND
530 IF S>0.33 THEN GOTO 670
540 FOR J=1 TO D
550 FOR K=1 TO D
560 LET I(K,D+1-J)=M(J,K)
570 NEXT K
580 NEXT J
590 LET R=R-0.33
600 FOR J=1 TO D
610 FOR K=1 TO D
620 LET M(J,K)=I(J,K)
630 NEXT K
640 NEXT J
650 IF R>0.1 THEN GOTO 540
660 GOTO 800
670 IF S>0.66 THEN GOTO 740
680 FOR J=1 TO D
690 FOR K=1 TO D
700 LET I(D+1-J,K)=M(J,K)
710 NEXT K
720 NEXT J
730 GOTO 600
740 FOR J=1 TO D
750 FOR K=1 TO D
760 LET I(J,D+1-K)=M(J,K)
770 NEXT K
780 NEXT J
790 GOTO 600
800 REM PRINT ROUTINES
810 LET VL=17-2*D 
820 LET VR=17+D 
830 LET HU=14-INT(D/2)
840 LET HL=16+INT(D/2) 
850 FOR J=VL TO VR
860 PRINT AT HU,J;"«"
870 PRINT AT HL,J;"«"
880 NEXT J
890 FOR J=1 TO D 
900 FOR K=1 TO D 
910 IF J=3 OR K=3 THEN GOTO 960
920 IF M(J,K)<10 THEN GOTO 950
930 PRINT AT HU+J,VL+1+(K-1)*3;M(J,K);"+"
940 GOTO 960
950 PRINT AT HU+J,VL+2+(K-1)*3;M(J,K);"+"
960 NEXT K
970 NEXT J
980 FOR J=HU TO HL
990 PRINT AT J,VL;"«"
1000 PRINT AT J,VR;"«"
1001 NEXT J
1005 PRINT AT 0,16;"TIME:"
1010 PRINT AT 2,17;"ALLOWED:600SECS"
1020 PRINT AT 1,17;"TAKEN :"
1030 PRINT AT 1,28;"SECS"
1100 REM MAGIC NUMBER
1110 LET MN=(D**3+D)/2+D*Y
1120 PRINT AT 1,2;"MAGIC NUMBER"
1130 PRINT AT 3,6;"       " 
1140 PRINT AT 3,5;"IS ";MN
1150 PRINT AT 6,3;"THE CLOCK"
1160 PRINT AT 7,2;"HAS STARTED"
1170 PRINT AT 21,0;"ENTER NUMBER THEN PRESS NEWLINE"
1200 REM    TIMER SET AND ENTER ROUTINE
1210 POKE 16436,255
1220 POKE 16437,255
1230 SLOW
1240 LET J=3
1250 FOR K=1 TO D
1255 IF K=J THEN GOTO 1380
1260 LET A$="??"
1270 PRINT AT HU+J,VL+1+(K-1)*3;A$
1275 INPUT A
1280 LET TIME=PEEK 16436+256*PEEK 16437
1285 LET TOT=(65536-TIME)/45+PREV
1290 PRINT AT 1,25;INT(TOT)
1305 PRINT AT HU+J,VL+1+(K-1)*3;"  " 
1310 IF A=M(J,K) THEN GOTO 1350
1320 LET A$="LL"
1330 IF A>M(J,K) THEN LET A$="HH"
1340 GOTO 1270
1350 LET Z=1
1360 IF M(J,K)<10 THEN LET Z=2
1370 PRINT AT HU+J,VL+Z+(K-1)*3;M(J,K);
1374 IF K=D THEN GOTO 1380
1376 PRINT "+"
1380 NEXT K
1400 LET K=3
1410 FOR J=1 TO D
1420 LET A$="??"
1430 PRINT AT HU+J,VL+1+(K-1)*3;A$
1435 INPUT A
1440 LET TIME=PEEK 16436+256*PEEK 16437
1445 LET TOT=(65536-TIME)/45+PREV
1450 PRINT AT 1,25;INT(TOT)
1465 PRINT AT HU+J,VL+1+(K-1)*3;"  "
1470 IF A=M(J,K) THEN GOTO 1510 
1480 LET A$="LL" 
1490 IF A>M(J,K) THEN LET A$="HH" 
1500 GOTO 1430 
1510 LET Z=1 
1520 IF M(J,K)<10 THEN LET Z=2 
1530 PRINT AT HU+J,VL+Z+(K-1)*3;M(J,K); 
1534 IF D=3 THEN GOTO 1540 
1536 PRINT "+" 
1540 NEXT J 
1550 PRINT AT 21,0;"                                "
1560 PRINT AT 7,9;"OPP" 
1600 REM EVALUATION 
1610 IF (65536-TIME)/45>D**3*2 THEN GOTO 1680 
1620 IF (65536-TIME)/45<D**3 THEN GOTO 1660 
1630 LET B=B+1 
1640 LET X=INT (0.5*(RND*((CODE D$-38)**2+1)))+1 
1645 LET Y=X-1 
1650 GOTO 1710 
1660 LET D=D+1 
1670 GOTO 1690 
1680 LET D=D-1 
1690 LET B=0  
1700 LET X=INT(RND*((CODE D$-38)**2+1))+1 
1705 LET Y=X-1 
1710 LET PREV=TOT 
1720 IF D=8 THEN GOTO 1910 
1730 IF D=2 THEN LET D=3 
1740 IF D=3 THEN LET B$="   NOVICE  "
1750 IF D=5 THEN LET B$="   EXPERT  "
1760 IF D=6 THEN LET B$="   MASTER  " 
1770 IF D=7 THEN LET B$="GRAND   MASTER" 
1780 IF D=4 THEN LET B$="  CHALLENGER" 
1790 PRINT AT 4,19;"YOU ARE A" 
1795 IF D=5 THEN PRINT AT 4,27;"AN" 
1800 PRINT AT 5,17;B$ 
1810 PRINT AT 6,18;"OF THE MAGIC" 
1812 PRINT AT 7,17;"SQUARE-CLASS ";D$ 
1825 PRINT AT 8,16;"             " 
1826 IF B=0 THEN GOTO 1835 
1830 PRINT AT 8,19;"WITH ";B;" BAR" 
1835 FOR J=1 TO 50 
1836 NEXT J 
1840 IF PREV<600 THEN GOTO 120 
1850 PRINT AT 1,2;"END OF GAME" 
1860 PRINT AT 3,3;"TYPE S TO" 
1870 PRINT AT 4,4;"RESTART" 
1890 IF INKEY$<>"S" THEN GOTO 1890 
1900 GOTO 95 
1910 PRINT AT 1,2;" EXCELLENT " 
1920 PRINT AT 3,3;"TRY NEXT " 
1930 PRINT AT 4,3;"DEGREE OF" 
1940 PRINT AT 5,3;"DIFFICULTY" 
1945 PRINT AT 6,3;"          "
1950 PRINT AT 7,2;" TYPE RUN "
1960 IF INKEY$<>"R" THEN GOTO 1960 
1970 GOTO 70 
9998 SAVE"MAGICSQUARE"
9999 RUN
MAGICSQUARE.P
(8.38 KiB) Downloaded 197 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 04/82

"LOWE MYSTERY PROGRAM "

/? Basic tool ?/

Contributor : XavSnap.

Code: Select all

0 REM LOWE MYSTERY PROGRAM 
10 LET A=16509
15 PRINT TAB 2;PEEK A*256+PEEK(A+1);" "; 
20 LET L = PEEK (A+2)+ 256* PEEK(A+3)-1 
29 LET A = A + 3
30 FOR N=1 TO L 
35 IF PEEK (N+A)<>126 THEN GOTO 50 
40 LET N=N+5 
45 GOTO 55 
50 PRINT CHR$ (PEEK (N + A));
55 NEXT N
60 LET A=A+N+1 
65 IF A<16914 THEN GOTO 15 
70 LET A$ = "\:'-9B25\.'.885\:'" 
75 FOR N = 1 TO LEN A$ 
80 FOR J = 1 TO 50
85 NEXT J
90 PRINT AT 16,13+N; CHR$ (CODE A$ (N) + 144)
95 NEXT N 
100 STOP
9000 SAVE"MISTERY"
9999 RUN
MISTERY.P
(1.34 KiB) Downloaded 193 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 06/83

" Matrix Mover " (KIMCALC)

/ Basic tool /

Contributor : Antipontifex.

Code: Select all

1 DIM A$(19,4,7) 
2 DIM B$(19,4,31)
9 STOP 
10 SLOW 
11 PRINT AT 0,23;"«kimcalc«"
12 DIM D$(7) 
15 PRINT AT 2,0;"««««««a««««««b««««««c««««««d«««" 
20 FOR A=1 TO 19
21 IF A<10 THEN PRINT AT A+2,0;"0";A;
22 IF A>9 THEN PRINT AT A+2,0;A;
25 FOR B=1 TO 4 
30 PRINT AT A+2,(B*7)-4;A$(A,B);
35 NEXT B
40 NEXT A
45 GOSUB 4000
50 LET C=1
60 LET R=1 
70 LET M$=INKEY$
80 IF M$="" THEN GOTO 70
85 LET CR=R
86 LET OC=C 
90 IF CODE M$=112 THEN LET R=R-1 
100 IF CODE M$=113 THEN LET R=R+1 
110 IF CODE M$=114 THEN LET C=C-1
120 IF CODE M$=115 THEN LET C=C+1 
125 IF CODE M$<112 OR CODE M$>115 THEN GOTO 300
130 IF R>19 THEN LET R=1
140 IF R<1 THEN LET R=19 
150 IF C>4 THEN LET C=1
155 IF C<1 THEN LET C=4
200 LET D$=CHR$ (CODE A$(R,C,1)+128)+CHR$ (CODE A$(R,C,2)+128)+CHR$ (CODE A$(R,C,3)+128)+CHR$ (CODE A$(R,C,4)+128)+CHR$ (CODE A$(R,C,5)+128)+CHR$ (CODE A$(R,C,6)+128)+CHR$ (CODE A$(R,C,7)+128) 
205 PRINT AT CR+2,(OC*7)-4;A$(CR,OC)
210 PRINT AT R+2,(C*7)-4;D$
220 PRINT AT 1,0;B$(R,C) 
230 GOTO 70
300 IF CODE M$=116 THEN GOTO 370 
301 IF CODE M$=119 THEN GOTO 1005 
302 IF CODE M$=117 THEN GOTO 2000 
303 IF CODE M$=218 THEN GOTO 3000
304 IF CODE M$=223 THEN GOTO 1000 
305 IF CODE M$=118 THEN GOTO 70
306 LET A$(R,C)="        "
307 PRINT AT R+2,(C*7)-4;"«««««««"
310 FOR A=1 TO 7 
313 IF CODE M$>111 AND CODE M$<116 THEN GOTO 85
315 IF CODE M$=118 THEN GOTO 70
316 IF CODE M$=26 THEN LET M$="" 
320 LET A$(R,C,A)=M$
330 PRINT AT R+2,(C*7)-5+A;CHR$(CODE A$(R,C,A)+128)
340 LET M$=INKEY$
345 IF M$="" THEN GOTO 340
350 NEXT A
360 GOTO 70
370 PRINT AT 0,0;"ENTER FORMULA"
376 PRINT AT 1,0;"                               "
377 LET B$(R,C)="                                "
380 FOR A=1 TO 31
385 LET M$=INKEY$
386 IF M$="" THEN GOTO 385 
387 IF CODE M$=26 THEN LET M$=""
400 IF CODE M$=118 THEN GOTO 470 
420 LET B$(R,C,A)=M$
430 PRINT AT 1,A-1;B$(R,C,A) 
460 NEXT A
470 PRINT AT 0,0;"              "
480 GOTO 70 
1000 FAST
1005 PRINT AT 0,0;"RECALCULATING - "
1009 FOR A=1 TO 19
1010 PRINT AT 0,16;A
1015 FOR B=1 TO 4
1020 IF B$(A,B)="                                " THEN GOTO 1300
1021 LET S=0 
1022 LET A$(A,B)=STR$ S
1025 LET W=0
1030 LET L=21
1035 GOTO 1080
1070 LET L=CODE B$(A,B,W)
1080 LET J=VAL B$(A,B,W+1 TO W+2) 
1090 LET K=CODE B$(A,B,W+3)-37 
1100 IF CODE A$(J,K)<28 OR CODE A$(J,K)>37 THEN GOTO 1275
1230 IF L=21 THEN LET S=VAL A$(A,B)+VAL A$(J,K)
1240 IF L=22 THEN LET S=VAL A$(A,B)-VAL A$(J,K)
1250 IF L=23 THEN LET S=VAL A$(A,B)*VAL A$(J,K)
1260 IF L=24 THEN LET S=VAL A$(A,B)/VAL A$(J,K)
1270 LET A$(A,B)=STR$ S
1275 LET W=W+4
1277 IF W=32 THEN GOTO 1280
1278 IF B$(A,B,W)<>" " THEN GOTO 1070
1280 PRINT AT A+2,(B*7)-4;"       "
1290 PRINT AT A+2,(B*7)-4,A$(A,B)
1300 NEXT B
1310 NEXT A
1315 SLOW 
1320 PRINT AT 0,0;"                 "
1330 GOTO 70
2000 COPY
2010 GOTO 70
3000 CLS
3010 PRINT AT 5,0;"SET TO RECORD THEN PRESS N/L"
3020 INPUT U$
3030 SAVE "X"
3040 CLS
3050 GOTO 10
4000 REM MESSAGE
4010 LET K$="%1%=print%,%2%=save%,%9%=formula%,%0%=calc«"
4020 LET X=PEEK 16396+256*PEEK 16397
4030 FOR N=760 TO 759+LEN K$
4040 LET Y=CODE K$(N-759)
4050 POKE N+X,Y
4060 NEXT N
4070 RETURN 
MATRIX.P
(3.89 KiB) Downloaded 186 times
Last edited by XavSnap on Thu Dec 03, 2020 2:27 pm, edited 1 time in total.
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 01/82

" Moon Lander "

/ Basic game/

Contributor : Antipontifex.

Code: Select all

0 REM MOONLANDER 
1 PAUSE 100 
5 LET F=200
10 LET X=INT(RND*36)
20 LET H=20
30 LET S=0 
38 CLS 
39 PRINT AT 20,0;"°®«®ªª®®®®®®®®®®³³³³³³®®®®®ªª«»¬"
40 PLOT X,H
41 PLOT X+1,H 
45 IF F>0 THEN IF INKEY$="S" THEN GOSUB 1000 
48 IF F>0 THEN IF INKEY$="D" THEN GOSUB 9520
49 IF F>0 THEN IF INKEY$="R" THEN GOSUB 9560 
55 IF H>4 THEN GOTO 4000
60 LET H=H-S
65 LET S=S+0.1
70 IF H>20 THEN LET H=20
90 GOTO 38 
1000 LET S=S-0.2
1010 LET F=F-5
1020 PRINT TAB 32+X/2;"V" 
1050 RETURN 
4010 PRINT AT 15,0;
5000 IF S<0.3 THEN PRINT "GREAT" 
5040 IF S>=0.3 OR X<16 OR X>21 THEN PRINT "SMASH" 
5050 PRINT "FUEL=";F
9510 GOTO 0 
9520 PRINT AT 20-H/2+1,X/2-1.5;"<"
9530 LET X=X+1
9540 LET F=F-1
9550 RETURN
9560 PRINT ">" 
9570 LET X=X-1
9580 LET F=F-1 
9600 RETURN
MOONLANDER.P
(1.61 KiB) Downloaded 186 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 01/82

" Memory economy: OXO 1k "

/ Basic game/


Contributor : XavSnap.

Code: Select all

# REM ·º½=*,ADG*·G*½A=A·*ºD.½Gr00O
     0  REM [HEX:\
02,05,08,14,17,1A,26,29,\
2C,17,02,2C,17,08,26,14,\
26,02,17,05,29,1B,08,2C,\
B7,68,7A,34 ]
2 PRINT"˜ «™ «š "
3 PRINT"««««««««"
4 PRINT"› «œ « "
5 PRINT"««««««««"
6 PRINT"ž «Ÿ «  "
7 LET X=16513
8 LET Q = PEEK 16396+256*PEEK 16397
9 LET A = INT (RND*CODE "/"+CODE "¶")
10 POKE Q+PEEK (X+A),CODE "O"
11 FOR G = CODE "¶" TO CODE "¹"
12 PRINT AT CODE "º",CODE "·";"goŽ"
15 INPUT A
16 PRINT AT CODE "º",CODE "¸";"««"
17 LET B = PEEK (X+A)
18 IF PEEK (Q+B)<> CODE " " THEN GOTO CODE "£"
19 POKE Q+B,CODE "X"
20 FOR A = CODE "¶" TO CODE "¹"
21 FOR B = CODE "¶" TO CODE "-" STEP CODE "¸"
25 IF PEEK ( Q+ PEEK (X+B)) + PEEK (Q+ PEEK (X+B+CODE"¶"))+ PEEK (Q+PEEK (X+B+CODE"·"))<>PEEK(X+A+CODE"/") THEN GOTO CODE "F" 
34 FOR C = CODE " " TO CODE "·"
36 LET S = Q+ PEEK (X+B+C)
38 IF PEEK S = CODE " " THEN GOTO CODE "M" 
40 NEXT C 
41 PRINT "YOU WIN" 
42 STOP 
43 NEXT B 
44 NEXT A 
45 GOTO CODE "Q"
50 POKE S, CODE "O"
51 IF A = CODE "·" THEN GOTO CODE "S"
52 NEXT G 
54 PRINT " DRAW"
55 STOP 
56 PRINT " I WIN" 
OXO.P
(853 Bytes) Downloaded 187 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 06/82

"ZXMinbug" John Sylvester Jun'82 page 50

/ ASM Tool/

Yu know what… it is not a minibug, but several big one.
:oops:

Unable to launch it...

Contributor : XavSnap.
Zxbug_06_82.zip
(3.51 KiB) Downloaded 174 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Zx81:Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 04/82

" Nim "

/ Basic game/

Contributor : Antipontifex.


Code: Select all

1000 GOTO 1030
1010 SAVE "NIM"
#1020 STOP
1030 GOSUB 2510
1040 GOSUB 1760
1050 GOSUB 1900
1060 IF G(1)+G(2)+G(3)+G(4)+G(5)=0 THEN PRINT "ROTTER. YOU WON."
1070 IF G(1)+G(2)+G(3)+G(4)+G(5)=0 THEN STOP
1080 GOSUB 1280
1090 IF G(1)+G(2)+G(3)+G(4)+G(5)=0 THEN PRINT "TEE-HEE. I WON"
1100 IF G(1)+G(2)+G(3)+G(4)+G(5)=0 THEN STOP
1110 IF U$="00000" THEN GOSUB 2220
1120 GOTO 1050
1130 CLS
1140 FOR I=1 TO 29 STEP 7
1150 FOR K=G(I/7+1) TO 1 STEP -1
1160 PRINT AT 20-K,I;"O"
1170 NEXT K
1180 PRINT AT 3,I-1;"(";G(I/7+1);")"
1190 PRINT AT 20,I;CHR$(157+I/7)
1200 NEXT I
1210 RETURN
1220 PRINT AT 0,0;"                                "
1230 PRINT AT 0,16;"                                "
1240 RETURN
1250 REM **********************
1260 REM BINARY SUM
1270 REM **********************
1280 LET B2=8
1290 FOR I=1 TO 5
1300 LET T$="00000"
1310 LET N=G(I)
1320 FOR J=5 TO 1 STEP -1
1330 IF N/2<>INT(N/2) THEN LET T$(J)="1"
1340 LET N=INT(N/2)
1350 NEXT J
1360 LET B1=VAL(T$)
1370 LET B2=B2+B1
1380 NEXT I
1390 REM ************************
1400 REM BINARY SUBTRACT
1410 REM ************************
1420 LET S$=STR$(B2)
1430 LET T$="00000"
1440 LET T$(6-LEN S$ TO 5)=S$
1450 LET U$="00000"
1460 FOR I=1 TO 5 
1470 LET N=VAL(T$(I))
1480 IF N/2<>INT(N/2) THEN GOTO 1510
1490 NEXT I 
1500 RETURN
1510 LET U$(I)="1"
1520 LET V$="00000"
1530 FOR J=I+1 TO 5
1540 LET N=VAL(T$(J))
1550 IF N/2<>INT (N/2) THEN LET V$(J)="1"
1560 NEXT J
1570 GOSUB 2330
1580 LET S=0
1590 REM **********************
1600 REM TRANSLATE FROM BINARY
1610 REM **********************
1620 FOR I=5 TO 1 STEP -1
1630 IF U$(I)<>"0" THEN LET S=S+2**(5-I)
1640 IF V$(I)="1" AND W$(I)="0" THEN LET S=S-2**(5-I)
1650 IF V$(I)="1" AND W$(I)="1" THEN LET S=S+2**(5-I)
1660 NEXT I
1670 REM ***********************
1680 REM ADJUST PILES
1690 REM ***********************
1700 PRINT AT 0,0;"I WILL TAKE ";S;" FROM PILE ";P
1710 PAUSE 130
1720 POKE 16437,255
1730 LET G(P)=G(P)-S
1740 GOSUB 1130
1750 RETURN
1760 REM **********************
1770 REM SET PILES INITIALLY
1780 REM **********************
1790 DIM G(5)
1800 LET G(1)=INT (RND*13)
1810 LET G(2)=INT (RND*13)
1820 LET G(3)=INT (RND*(27-G(1)-G(2)))
1830 IF G(3)>16 THEN LET G(3)=16
1840 LET G(4)=INT(RND*(30-G(3)-G(2)-G(1)))
1850 IF G(4)> 16 THEN LET G(4)=16
1860 LET G(5)=32-G(4)-G(3)-G(2)-G(1)
1870 IF G(5)>16 THEN GOTO 1800
1880 GOSUB 1130
1890 RETURN
1900 REM **********************
1910 REM ACCEPT MOVE
1920 REM **********************
1930 PRINT AT 0,0;"WHICH PILE ";
1940 INPUT M1
1950 PRINT M1
1960 IF M1<6 AND M1>0 THEN GOTO 2020
1970 PRINT AT 0,0;"THERE FIRE ONLY FIVE FILES."
1980 PAUSE 100
1990 POKE 16437,255 
2000 GOSUB 1220
2010 GOTO 1930
2020 IF G(M1)>0 THEN GOTO 2080
2030 PRINT AT 0,16; "NOTHING IN THAT PILE."
2040 PAUSE 100
2050 POKE 16437,255
2060 GOSUB 1220
2070 GOTO 1930
2080 PRINT AT 0,16;"HOW MANY?";
2090 INPUT M2
2100 PRINT M2
2110 IF M2>0 AND M2<=G(M1) THEN GOTO 2170
2120 PRINT AT 0,16;"YOU CANT.  "
2130 PAUSE 100
2140 POKE 16437,255
2150 GOSUB 1230
2160 GOTO 2080
2170 LET G(M1)=G(M1)-M2
2180 PAUSE 100
2190 POKE 16437,255
2200 GOSUB 1130
2210 RETURN
2220 REM **********************
2230 REM SAFE POSITION
2240 REM **********************
2250 LET S=0
2260 FOR I=1 TO 5
2270 IF G(I)>S THEN LET P=I
2280 IF G(I)>S THEN LET S=G(I)
2290 NEXT I
2300 LET S=1 
2310 GOSUB 1670
2320 RETURN
2330 REM ************************
2340 REM PILE TO DE ALTERED
2350 REM ************************
2360 LET PILE=2**(5-I)
2370 FOR I=1 TO 5
2380 IF G(I)>=PILE AND G(I)<2*PILE THEN GOTO 2430
2400 IF G(I)-PILE>=2*PILE THEN GOTO 2430
2410 NEXT I
2420 STOP
2430 LET P=I
2440 LET W$="00000"
2450 LET C=G(P)
2460 FOR I=1 TO 5
2470 IF C/2<>INT(C/2) THEN LET W$(6-I)="1"
2480 LET C=INT(C/2)
2490 NEXT I
2500 RETURN
2510 REM **********************
2520 REM INSTRUCTIONS
2530 REM **********************
2540 PRINT "I WILL DISPLAY FIVE PILES OF","COUNTERS. ON EACH MOVE YOU CAN","TAKE ANY NUMBER OF COUNTERS,UP","TO AND INCLUDING ALL OF THEM--","BUT ONLY FROM ONE PILE.",,,"THE WINNER IS THE ONE TO  TAKE","THE LAST COUNTER."
2550 PRINT
2560 PRINT "PRESS NEWLINE TO CONTINUE."
2570 INPUT A$
2580 RETURN 
NIM.P
(4.87 KiB) Downloaded 202 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Zx81:Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 10/82

" Ohms law "

/ Basic tutorial/

Contributor : Antipontifex.

Code: Select all

1 LET A$="«ohms«law«" 
2 LET B$=" OHMS DEALS WITH metals." 
3 LET C$="«the«current«in«a«metal«sample««at«constant«temperature«is««««««proportional«to«the«voltage«««««between«its«ends%." 
4 LET D$="THE LAW RELATES THE current IN Ametal SAMPLE TO THE voltage     BETWEEN ITS ENDS."
5 LET E$=" AN insulator DOES NOT PASS     CURRENT.OHMS LAW CAN SAY NOTHINGABOUT INSULATORS THEN."
6 LET F$=" THE BEHAVIOUR OF SO-CALLED semi%-conductors CAN BE COMPLEX. WE  SHALL DEAL WITH THEM LATER." 
7 LET G$=" THERE ARE OTHER conductors THANMETALS. SOLUTIONS OF SOME       COMPOUNDS ARE AN EXAMPLE. THESE DO NOT ALL OBEY OHMS LAW." 
8 LET H$=" HERE IS OHMS LAW AGAIN:"
20 PRINT TAB 11;A$ 
30 PRINT ,,"FIRST STATED IN 1840, THIS MAJORLAW OF PHYSICS IS CONCERNED WITHELECTRIC CURRENTS INPURE METALS.WE CALL THESE  ohmic«conductors."
40 PRINT ,, D$ 
50 PRINT ,," HERE IS THE LAW:" 
60 PRINT ,, C$ 
70 GOSUB 1100
110 GOSUB 1000 
120 PRINT AT 10,0;"a.  OHMS LAW DEALS WITH"
130 PRINT " %1 CONDUCTORS",," %2 INSULATORS",," %3 SEMI-CONDUCTORS"," %4 METALS" 
170 GOSUB 1050
180 IF A=4 THEN PRINT "yes"
190 IF A<>4 THEN PRINT "no"
200 PRINT B$
201 IF A<>4 THEN GOTO 200+A*10 
202 PRINT ,,D$
203 PRINT ,,E$
204 PRINT ,,F$ 
205 PRINT ,,G$
206 PRINT ,,B$
207 GOSUB 1100
208 IF A <>4 THEN GOTO 110
209 GOTO 250 
210 PRINT ,,G$
211 PRINT ,,H$ 
212 PRINT ,,C$ 
213 GOSUB 1100
214 GOTO 110 
220 PRINT ,,E$
221 PRINT ,,H$
222 PRINT ,,C$
223 GOSUB 1100
224 GOTO 110
230 PRINT ,,F$
231 PRINT ,,H$
232 PRINT ,,C$
233 GOSUB 1100
234 GOTO 110 
250 REM start«next«frame
251 PRINT "start«of«next«frame"
999 STOP 
1000 REM headings
1010 PRINT TAB 11;A$,,
1020 PRINT "type«the«number«by«your«answer."
1030 PRINT ,,,,"WHICH COMPLETES THE SENTENCE?" 
1040 RETURN
1050 REM response
1060 INPUT A
1070 IF A<1 OR A> 4 THEN GOTO 1050
1080 CLS 
1090 RETURN
1100 REM continue 
1110 PRINT AT 21,0;"PRESS n%/l TO GO ON." 
1120 INPUT A$
1130 CLS
1140 RETURN
9998 SAVE "OHMSLAW"
9999 RUN
OHMSLAW.P
(2.58 KiB) Downloaded 198 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Zx81:Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 10/82

" WORDY v.3 "

/ Basic tool/

Contributor : Antipontifex.

Code: Select all

10 REM -WORDY 3 
11 REM -A.F.WHIDDETT
12 REM -24.3.82
20 DIM A$(10,640)
30 LET B$=""
40 LET D$=""
50 LET POS=1
60 LET PAGE=1
70 PRINT "WORDY3 ENTER PROGRAM NAME-"
110 INPUT Z$
115 IF Z$="" THEN GOTO 9050
120 PRINT "SET UP TAPE DECK THEN PRESS(N/L)"
130 INPUT X$
140 SAVE Z$
160 CLS
170 PRINT "¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸¸" 
180 PRINT "  WORDY 3 BY A.F.WHIDDETT"
190 PRINT "®®®®®®®®®®®®®®®®®®®®®®®®®®®®®®®®"  
200 PRINT AT 4,2;"  %1:SAVE ON TAPE" 
210 PRINT AT 6,2;"  %2:SEND TO PRINTER"
220 PRINT AT 8,2;"  %3:WRITE PAGE"
230 PRINT AT 10,2;"  %4:EDIT PAGE"
240 PRINT AT 12,2;"  %5:CLEAR PAGE"
245 PRINT AT 14,0;"    ENTER OPTION (%1 TO %5)"
250 PRINT AT 14,25;"Š",,,,,,,
260 LET X$=INKEY$
270 IF X$="1" THEN GOTO 70
280 IF X$="2" THEN GOTO 350
295 PRINT AT 14,25;"?",,,,,,,
300 IF X$="3" THEN GOTO 500
310 IF X$="4" THEN GOTO 800
320 IF X$="5" THEN GOTO 4000
330 GOTO 250
360 PRINT "ENTER PAGE TO BE PRINTED OUT"
370 INPUT X
380 IF X=11 THEN GOTO 420
390 IF X=12 THEN GOTO 150
395 IF X>11 OR X<1 THEN GOTO 9030
400 LPRINT A$(X)
410 GOTO 430
420 FOR X=1 TO 10
422 LPRINT A$(X)
424 NEXT X
430 PRINT "  ANYMORE"
440 LET X$=INKEY$
480 IF X$="Y" THEN GOTO 350
490 IF X$="N" THEN GOTO 150
495 GOTO 440
520 PRINT "ENTER PAGE FOR WRITING ON"
530 INPUT X
540 IF X>10 OR X<1 THEN GOTO 9030
545 LET POS=1
550 PRINT AT 21,0;" MODE:WRITING    ";AT 21,22;"PAGE:";X
580 PRINT AT 20,0;"««««««««««««««««««««««««««««««««"  
600 PRINT AT 0,0;A$(X)
605 POKE 16441,20
606 POKE 16442,30
620 LET WL=INT(POS/32)
630 LET WC=POS-WL*32-1
635 IF POS/32=INT(POS/32) THEN GOSUB 8000
640 PRINT AT WL,WC;"c"
650 IF INKEY$="" THEN GOTO 650
660 LET X$=INKEY$
670 IF X$=CHR$ 224 THEN GOTO 150 
675 IF X$=CHR$ 121 THEN GOTO 731 
680 IF X$=CHR$ 118 THEN GOTO 740 
685 IF X$=CHR$ 228 THEN GOTO 3000
686 IF X$=CHR$ 217 THEN GOTO 850 
687 IF X$=CHR$ 121 THEN GOTO 8500
690 LET A$(X,POS)=X$
700 PRINT AT WL,WC;A$(X,POS)
710 LET POS=POS+1
720 IF POS>640 OR POS<1 THEN GOTO 3800
730 GOTO 620
731 LET UU=(WL+1)*32-POS
732 LET POS=POS+UU+1
733 PRINT AT WL,WC;A$(X,POS-UU-1)
734 GOTO 720
740 LET X$=" "
750 GOTO 690
810 PRINT "ENTER PAGE FOR EDITING"
820 INPUT X
830 IF X>10 OR X<1 THEN GOTO 9030
840 LET POS=1 
850 PRINT AT 20,0;"««««««««««««««««««««««««««««««««"
860 PRINT AT 0,0;A$(X)
870 LET WL=INT(POS/32)
880 LET WC=POS-WL*32-1
885 IF POS/32=INT(POS/32) THEN GOSUB 8000
890 PRINT AT WL,WC;CHR$(128+CODE A$(X,POS)) 
900 PRINT AT WL,WC;A$(X,POS)
905 IF INKEY$="" THEN GOTO 890
910 LET X$=INKEY$
920 LET POS=POS+(X$="8")-(X$="5")+32*(X$="6")-32*(X$="7")
930 IF POS>640 OR POS<1 THEN GOTO 9070 
940 IF CODE X$<37 AND CODE X$>32 THEN GOTO 870
950 IF X$="H" THEN LET POS=1
955 IF X$="D" THEN GOTO 2200
960 IF X$="S" THEN GOTO 1100
970 IF X$="L" THEN GOTO 1200
980 IF X$="A" THEN GOTO 1500
990 IF X$="I" THEN GOTO 1300
1000 IF X$="C" THEN GOTO 1400
1010 IF X$="B" THEN GOTO 1600 
1020 IF X$="T" THEN GOTO 1700
1030 IF X$="1" THEN GOTO 1800 
1035 IF X$="2" THEN GOTO 9950
1040 IF X$="P" THEN GOTO 1900 
1050 IF X$="R" THEN GOTO 2000 
1060 IF X$="E" THEN GOTO 2400 
1070 IF X$="O" THEN LET B$="" 
1075 IF X$="J" THEN GOTO 7000 
1080 IF X$="W" THEN GOTO 3500 
1085 IF X$="M" THEN GOTO 8600
1090 GOTO 870
1100 LET B$=A$(X,640)+B$
1120 LET A$(X)=A$(X,1 TO POS-1)+" "+A$(X,POS TO 640)
1130 LET POS=POS+1
1135 IF LEN B$>200 THEN GOTO 9090
1140 GOTO 860
1210 LET B$=A$(X,640-32 TO 640)+B$
1220 LET A$(X)=A$(X,1 TO POS-1)+"                                "
1230 IF LEN B$>200 THEN GOTO 9090
1240 GOTO 860
1310 PRINT AT 21,0;"ENTER TEXT              "
1320 INPUT X$
1330 LET A=LEN X$
1340 LET B$=A$(X,640-A TO 640)+B$
1350 LET A$(X)=A$(X,1 TO POS-1)+X$+A$(X,POS TO 640)
1360 IF LEN B$>200 THEN GOTO 9090
1370 GOTO 850
1410 LET A$(X,POS)=" "
1420 GOTO 860
1510 GOSUB 2500
1515 IF X=10 THEN GOTO 9010
1520 LET X=X+1
1530 GOTO 850
1610 GOSUB 2500
1615 IF X=1 THEN GOTO 9010
1620 LET X=X-1
1630 GOTO 850
1710 PAUSE 100
1720 IF INKEY$="" THEN GOTO 1720
1740 LET A$(X,POS)=INKEY$
1750 GOTO 860
1810 PRINT AT 21,0;"AMOUNT?"
1820 INPUT A
1830 LET D$=A$(X,POS-A TO POS-1)
1840 LET A$(X)=A$(X,1 TO POS-A-1)+A$(X,POS TO 640)
1850 GOTO 850
1910 LET A$(X)=A$(X,1 TO POS-1)+D$+A$(X,POS TO 640)
1920 LET D$=""
1930 GOTO 860
2010 GOSUB 2500
2020 GOTO 850
2300 IF B$="" THEN LET A$(X)=A$(X,1 TO POS-2)+A$(X,POS TO 640) 
2310 IF B$="" THEN LET A$(X)=A$(X,1 TO POS-2)+B$(1) 
2320 IF B$<>"" THEN LET B$=B$(2 TO )
2330 LET POS=POS-1
2340 GOTO 860
2410 GOSUB 2500
2420 GOTO 150
2502 IF B$="" THEN RETURN
2505 FAST
2510 LET A=LEN B$
2520 FOR B=X+1 TO 9
2530 LET C$=A$(B,640-A TO 640)
2540 LET A$(B)=B$+A$(B,1 TO 640-A-1)
2550 LET B$=C$ 
2560 NEXT B
2570 LET B$=""
2580 SLOW
2590 RETURN
3000 LET POS=POS-1
3005 LET A$(X,POS+1)=" "
3010 GOTO 600 
3500 GOSUB 2500
3510 GOTO 550
3800 LET X=X+1
3810 IF X>10 THEN GOTO 9010
3815 LET POS=1
3820 GOTO 550
4000 PRINT "  PAGE TO CLEAR?"
4010 INPUT X
4020 IF X>10 OR X<1 THEN GOTO 9030
4030 LET A$(X)=""
4040 GOTO 150
7005 LET GH=0
7007 LET AS=2
7010 FAST
7030 FOR Z=1 TO 640-32 STEP 32
7040 FOR Y=Z+31 TO Z STEP -1
7042 IF A$(X,Y)="<" THEN GOTO 7115
7050 IF A$(X,Y)=">" THEN GOTO 7100
7052 IF A$(X,Y)<>" " THEN GOTO 7065
7056 LET GH=GH+1
7060 NEXT Y
7065 LET A$(X)=A$(X,1 TO Z+31-GH)+A$(X,Z+31+1 TO 640)
7070 FOR Y=Z TO Z+31
7075 IF GH=0 THEN GOTO 7100
7080 IF A$(X,Y)=" " THEN GOSUB 7500
7090 NEXT Y 
7095 IF GH<>0 THEN GOTO 7800
7100 LET GH=0
7102 LET AS=2
7105 NEXT Z
7115 SLOW
7120 GOTO 850
7510 LET A$(X)=A$(X,1 TO Y-1)+""+A$(X,Y TO 640)
7515 LET GH=GH-1
7518 LET Y=Y+A$
7520 RETURN
7800 LET AS=AS+1
7810 GOTO 7070
8000 LET WC=31
8010 LET WL=WL-1
8020 RETURN
8605 FAST
8610 LET WL=INT(POS/32)
8615 FAST
8620 LET WC=POS-WL*32-1
8630 IF POS/32=INT(POS/32) THEN GOSUB 8000
8640 PRINT AT WL,WC;"m"
8645 SLOW
8650 IF INKEY$="" THEN GOTO 8650
8655 PRINT AT WL,WC;A$(X,POS)
8660 LET X$=INKEY$
8665 IF X$=CHR$ 118 THEN GOTO 85
8670 LET POS=POS+(X$="8")-(X$="5")+32*(X$="6")-32*(X$="7")
8690 GOTO 8610
9010 PRINT AT 21,0;"<ERROR> YOU HAVE USED ALL FILES"
9020 GOTO 9910
9030 PRINT AT 21,0;"<ERROR> THERE IS NO SUCH PAGE"
9040 GOTO 9910
9050 PRINT AT 21,0;"<ERROR> PROGRAM NAME IS INVALID"
9060 GOTO 9910
9070 PRINT AT 21,0;"<ERROR> RUNNING INTO NEXT PAGE"
9080 GOTO 9910
9090 PRINT AT 21,0;"<ERROR> WORKING SUFFER IS FULL"
9100 GOSUB 2500
9110 GOTO 9910
9120 PRINT AT 21,0;"<ERROR>TEXT INSERT. IS TOO LARGE"
9130 FOR F=1 TO 20
9140 NEXT F
9150 GOTO 850
9910 PAUSE 100 
9920 GOTO 150
9950 LET DF=PEEK 16396+256*PEEK 16397
9955 LET A=0
9960 LET DF=DF+1
9965 IF PEEK DF=118 THEN GOTO 9960
9970 LET A=A+1
9975 LET A$(X,A)=CHR$ PEEK DF
9980 IF A<640 THEN GOTO 9960
9990 GOTO 850
9999 REM (C) A.F.WHIDDETT

Code: Select all

10 PRINT"\
½¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿½\
  wordy«vš BY A.F. WHIDDETT     \
  ¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿¿½     \
KEYS: 5-6-7-8 cursors           \
h:HOMES CURSOR                  \
d:DELETE CHAR.    shiftw: EDIT \
s:ADD A SPACE                   \
t:CHANGE CHAR.     ¾¾¾¾¾¾¾¾¾¾¾¾¾\
c:CLEAR CHAR.     O            O\
l:DELETE LINE     O DEAR SIR   O\
b:PREVIOUS PAGE   O     /MADAM O\
a:NEXT PAGE       O            O\
i:INSERT TEXT     O PLEASE     O\
˜:PASTE TEXT      O            O\
p:COPY  TEXT      O FIND       O\
o:CLEAR BUFFER    O            O\
r:REPLACE BUFFER  O ENCLOSED A O\
j:JUSTIFIES TEXT  O            O\
e:EXIT TO MENU    O            O"

WORDY3.P
(13.39 KiB) Downloaded 179 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
User avatar
XavSnap
Posts: 1940
Joined: Sat May 10, 2008 4:23 pm
Location: 'Zx81 France' Fb group.

Re: [Zx81:Type-Ins] "Your Computer" campaign...

Post by XavSnap »

"Your computer" 01/83

" Zxtra Wide Text "

/ ASM tool/

:? Something wrong.

Unable to launch it...

Contributor : XavSnap.

DEEP THOUGHT.P
(2.23 KiB) Downloaded 187 times
DEMO1.P
(1.21 KiB) Downloaded 184 times
DEMO2.P
(1.3 KiB) Downloaded 185 times
Xavier ...on the Facebook groupe : "Zx81 France"(fr)
Post Reply